/* This data set is taken from the case ARKANSAS EDUCATION ASSOCIATION
V. BOARD OF EDUCATION. It concerns a class action claim of
discrimination in salaries. Black teachers in the Portland,
Arkansas School District alleged that the school district discriminated
in recruitment, assignment and utilization of teachers, and in
salaries. The employment data for the 1967-68 school year are
reproduced below. The various variables are defined as follows:
y = salary: Annual salary
x0 = Race Character: Race of Teacher 1=black 0=white
x1 = Administration duties (principal or superintendent)
1 = yes 0 = no
x2 = College: Had a college degree
1 = yes 0 = no
x3 = Grad. degree: Had an advanced degree
1 = yes 0 = no
x4 = Certification: Certification for high school teaching
1 = Certified to teach at high school level
0 = Certified only at elementary level
x5 = Experience: Years of teaching experience
1 = 0 - 10 years
2 = 11 - 20 years
3 = 21 or more years
For additional information see the paper by Rick Watson
"Regression Methods in Discrimination Litigation" May 7, 1998
Term paper in Eco 5352 Spring, 1998.
*/
data salaries;
input y x0 x1 x2 x3 x4 x5;
cards;
4500 1 0 1 0 1 1
5643 0 0 1 0 0 3
4100 0 0 1 0 0 2
6500 0 1 1 1 1 1
6000 0 0 1 1 1 1
6000 0 0 1 1 1 1
5947 0 0 1 0 1 2
5000 0 0 1 0 1 1
4356 0 0 1 0 1 1
5519 0 0 1 0 0 3
5768 0 0 1 1 0 2
5792 0 0 1 0 1 2
8636 0 1 1 1 1 3
6773 0 0 1 0 1 2
5966 0 0 1 0 0 3
5900 0 0 1 0 1 1
5500 0 0 1 0 1 1
5300 0 0 1 0 1 1
6189 0 1 1 1 0 3
4500 1 0 1 0 0 3
5500 1 0 1 0 1 1
4300 1 0 1 0 0 2
4500 1 0 1 0 1 2
4500 1 0 1 0 0 3
4500 1 0 1 0 0 3
4500 1 0 1 0 1 1
4500 1 0 1 0 0 1
4700 1 0 1 0 1 1
4500 1 0 1 0 0 3
4800 1 0 1 0 1 1
4500 1 0 1 0 1 1
4500 0 0 0 0 1 1
6400 0 1 1 1 0 1
;
proc reg data=salaries;
model y = x0 x1 x2 x3 x4 x5;
model y = x0 x1 x3 x4 x5;
title 'Regression Analysis of Discrimation';
data salaries;
set salaries;
if x5 = 1 then z1 = 1; else z1 = 0;
if x5 = 2 then z2 = 1; else z2 = 0;
if x5 = 3 then z3 = 1; else z3 = 0;
proc print data = salaries;
/* Here we test that the decade to decade increments to
salary arising from experience are equal across decades.
We can use the test statement or we can get the result
by computing an F-statistic using the restricted versus
unrestricted equations approach. */
proc reg data=salaries;
model y = x0 x1 x2 x3 x4 z2 z3;
test z3 = 2*z2;
run;
proc autoreg data=salaries;
model y = x0 x1 x2 x3 x4 x5;
hetero x5 / link = linear test = lm;
model y = x0 x1 x3 x4 x5;
hetero x5 / link = linear test = lm;
title 'Tests of Heteroscedasticy';
run;