use "C:\data\03728-0001-data.dta", clear
keep if sex==2
* women
keep if age > = 40
* completed fertility
keep if year==2002|year==1998|year==1994|year==1990|year==1986|year==1982|year==1978|year==1974
ren childs kids
drop if kids ==.
drop if age ==.
drop if sibs ==.
drop if educ ==.
gen afb = agekdbrn
gen city16=(res16>=4)&(res16<=6)
gen lowinc16 = (incom16==1)|(incom16==2)
gen immig = (born ==2)|(parborn==8)
replace race = racecen1 if year == 2002
gen white = race == 1
label var afb "woman's age when 1st child born"
label var white "=1 if r's race is white"
label var immig "=1 if respondent or both r's parents born abroad"
label var lowinc16 "=1 if income is below average income at age 16"
label var city16 "=1 if respondent lived in a city (pop>50000) at age 16"
keep year sibs kids age afb educ white city16 lowinc16 immig
order kids age educ year sibs afb white city16 lowinc16 immig
gen trend = year - 1974
gen childless = kids == 0
* The next two equations are attempting to replicate the results
* in Table 4.1 in the Textbook
* The point estimates don't exactly match those in the book.
* W&B may have used some computer package other than STATA
probit childless trend educ white sibs
logit childless trend educ white sibs
* Here we are attempting to replicate the Linear Probablity Model
* that W&B produce in Example 4.1, p. 101. We use heteroskedasticity-
* consistent standard errors for the coefficient estimates
reg childless trend educ white sibs, vce(robust)
* Now to turn to replicating the results reported in Table 3.1 in W&B
probit childless
probit childless trend
probit childless trend educ white sibs
* Now let us replicate the results in Table 4.6 in W&B
* Use the tabulate statement to get the cutoff probability
* for producing the classification table
tabulate childless
* Even though Table 4.6 does not report classificaiton table results
* we generate them here anyway
probit childless trend educ white sibs
estat classification , cutoff(0.1445)
lroc childless
logit childless trend educ white sibs
estat classification, cutoff(0.1445)
lroc childless